Manual       Imágenes      



► Comandos

       ► Lista

 

Contenido

  1. Secuencias y series
  2. Extracción de un elemento
  3. Reordenaciones
  4. Obtención de un resultado numérico
  5. Listas desplegables
  6. Sub-listas
  7. Operaciones con listas
Secuencias y series
Sintaxis Comentario
ListaIteración [f(x), x0, n] Lista de longitud n + 1 cuyos elementos son iteraciones de la función f empezando con el valor x0.
  • ListaIteración[x², 3, 2] devuelve {3, 9, 81}
Secuencia [e(t), t, t1, t2]

Secuencia [e(t), t, t1, t2, k]

Lista de objetos creados usando la expresión e y el parámetro t de un rango que va desde el número t1 al número t2 (opcionalmente, con incremento k).
  • L = Secuencia[(2, t), t, 1, 5]
    crea la lista de puntos {(2,1), ..., (2,5)}. Al no especificar un incremento, por defecto se toma 1.
  • L = Secuencia[(2, t), t, 1, 5, 0.5]
    crea una lista de puntos cuyas ordenadas van del 1 al 5 con un incremento de paso de 0.5.

Como los parámetros t1 y t2 son dinámicos, se pueden emplear valores de deslizadores.

Secuencia [n] Lista {1, ..., n}
  • 2^Secuencia[4] devuelve {2, 4, 8, 16}
Zip [expresión, variable1, L1, variable2, L2, ...] Lista de objetos obtenidos al sustituir en la expresión, las variables por elementos sucesivos de las correspondientes listas. Cada variable se sustituye por el primer elemento de cada lista, después por el segundo, etc.

 

Los elementos de cada lista deben ser del mismo tipo.

 

Es una forma más breve de introducir ciertas secuencias de comandos. Por ejemplo, si L1 y L2 son dos listas de longitudes n1 y n2, entonces:

Zip[PuntoMedio[A,B], A, L1, B, L2]

equivale a:

Secuencia[PuntoMedio[Elemento[L1, k], Elemento[L2, k]], k, 1, Min[n1, n2]]

La longitud de la lista resultante es el mínimo de las longitudes de las listas de L1, L2 ...

  • Si P, Q, R, S y T son algunos puntos, entonces (observar que A y B no están definidos, son argumentos abstractos):

    Zip[PuntoMedio[A ,B], A, {P, Q}, B, {R, S, T}] devuelve una lista conteniendo los puntos medios de los segmentos PR y QS.
Extracción de un elemento
Sintaxis Comentario
Elemento [L, n] Elemento enésimo de una lista L.
  • Si L = {1, (2, 4), "re"}
    entonces Elemento[L, 3] devuelve "re".
Elemento [L, n1, n2 ...] Dada una colección de listas anidadas L = {L1, L2 ...}, elige el elemento n1-ésimo de L, que a su vez es una lista, y dentro de ella toma el elemento n2-ésimo (que a su vez puede ser una lista) y así sucesivamente.
  • Si L = {{"a"}, {1, 2}, {{0}, {1, 2}, {"do", "re"}}} entonces:
    Elemento[L, 3, 3, 2] devuelve "re"
    Elemento[L, 3, 2, 2] devuelve 2

ElementoAleatorio [L]

Elige al azar, con probabilidad uniforme , un elemento de la lista L. Todos los elementos de la lista deben ser del mismo tipo.
  • ElementoAleatorio[{Vértices[Polígono[(1,1), (3,0), 7]]}]
    devuelve un vértice, elegido al azar, del polígono.
Reordenaciones
Sintaxis Comentario
Invierte [L] Invierte el orden de los elementos de la lista L.
Mezcla [L] Reordena aleatoriamente los elementos de la lista L.

 

Los elementos volverán a mezclarse cada vez que pulsemos en Menú Vista Recálculo de Todos los Objetos (o pulsemos F9).

Ordena [L] Ordena una lista de números, textos o puntos (ordenados por abscisas).

 

Las listas a ser ordenadas deben contener elementos del mismo tipo.

  • Ordena[{(3,2), (2,5), (4,1)}] devuelve {(2, 5), (3, 2), (4, 1)}

 

El orden del código de la letra ñ y las vocales con tilde no corresponde al alfabético:

  • Ordena[{"pétalo", "pistilo"}] devuelve {"pistilo", "pétalo"}

 

Se puede emplear este comando para trazar la poligonal de una lista de puntos, una vez ordenados por sus abscisas:

 

A=(3,1)     B=(5,3)     C=(2,4)     L = Ordena[{A, B, C}]


L' = Secuencia[Segmento[Elemento[L, s], Elemento[L, s+1]],
s, 1, Longitud[L] - 1]

Unico [L] Ordena la lista L de números o textos en orden ascendente, evitando repeticiones.

 

Equivale a Ordena[Unión[L,{}]]

  • Unico[{3, 2, 2, 1}] devuelve {1, 2, 3}
  • Unico[{"c", "b", "b", "a"}] devuelve {"a", "b", "c"}

En la Vista se puede usar cualquier tipo de lista, pero omite la reordenación.

Obtención de un resultado numérico
Sintaxis   Comentario
CuentaSi [TF, L]   Número de elementos de la lista L que satisfacen la condición TF.
  • CuentaSi [x < 3, {1, 2, 3, 4, 5}] devuelve 2
  • CuentaSi [x < 3, A1:A10]
IndiceDe [a, L]   Posición del primer elemento de la lista L que coincide con el objeto a.
  • IndiceDe[5,{1,3,5,2,5,4}] devuelve 3
IndiceDe [a, L, n]   Posición, a partir de la enésima, del primer elemento de la lista L que coincide con el objeto a.
  • IndiceDe[5,{1,3,5,2,5,4}, 4] devuelve 5
Longitud [L] Longitud (número de elementos) de la lista L.
Máximo [L] Máximo valor de los elementos de la lista de números L.
Media [L] Media de los datos de la lista L.

Mínimo [L]

Mínimo valor de los elementos de la lista de números L.
Producto [L]   Producto de todos los elementos de la lista L.
Producto [L, n]   Producto de los n primeros elementos de la lista L.
Suma [L]

Suma [L, n]

Suma de todos los elementos de la lista L, o los n primeros.

 

Los elementos pueden ser números, puntos, vectores, funciones y textos (en este último caso, los une).

  • Suma[{1, 2, 3}] devuelve 6
  • Suma[{1, 2, 3, 4, 5, 6}, 4] devuelve 10
  • Suma[{x², x³}] devuelve la función f(x) = x² + x³
  • Suma[Secuencia[k, k, 1, 100]] devuelve 5050
  • Suma[{(1, 2), (2, 3)}] devuelve el punto A = (3, 5)
  • Suma[{(1, 2), 3}] devuelve el punto B = (4, 2)
  • Suma[{"a","b","c"}] devuelve el texto '"abc"
Listas desplegables
Sintaxis Comentario
ElementoElegido [L] Devuelve el elemento elegido en la lista desplegable.

IndiceElegido [L]

Devuelve el índice del elemento elegido en la lista desplegable.
Sub-listas
Sintaxis   Comentario
ConservaSi [TF, L]   Sub-lista de la lista L cuyos elementos satisfacen la condición TF.
  • ConservaSi[x < 3, {1, 2, 3, 4, 1, 5, 6}] devuelve {1, 2, 1}
EliminaIndefinidos [L]   Sub-lista resultado de eliminar los objetos indefinidos de la lista L.
  • EliminaIndefinidos [Secuencia [(-1)^s, s, 1, 3, 0.5]]
    elimina los elementos 2º y 4º de la secuencia, pues las expresiones (−1)1.5 y (−1)2.5 no están definidas.

Extrae [L, m, n]

Sub-lista de la lista L con los elementos posicionados entre m y n, inclusive.
Muestra [L, n]   Sub-lista de n elementos tomados aleatoriamente de la lista L. Un mismo elemento puede ser escogido más de una vez (extracciones con reposición). Para evitarlo, la condición TF debe ser falsa (extracciones sin reposición).
Primero [L]

Primero [L, n]

  Sub-lista de la lista L con el primer elemento, o los n primeros.

Ultimo [L]

Ultimo [L, n]

  Sub-lista de la lista L con el último elemento, o los n últimos.
Unico [L]   Sub-lista de la lista L sin elementos repetidos.
  • Unico[{1, x, x, 1, a}] devuelve {x, 1, a}

Si no se usa en la Vista y la lista es de números o de textos, reordena además los elementos.

Operaciones con listas
Sintaxis   Comentario
Anexa [L, a]

Anexa [a, L]

  Añade el objeto a al final o al principio de la lista L.
  • Anexa[{1, 2, 3}, 4] devuelve {1, 2, 3, 4}
  • Anexa[4, {1, 2, 3}] devuelve {4, 1, 2, 3}
Clases [L, x0, ancho]   Lista ordenada de extremos de los intervalos de clase, de ancho dado, que comenzando en x0 abarcan todos los datos de la lista L, desde x0 hasta el mayor de ellos.
  • Clases[{3, 7, 9, 5, 8, 7, 4}, 0, 1.5]
    devuelve {0, 1.5, 3, 4.5, 6, 7.5, 9}
Encadena [L1, L2 ...]

Encadena [{L1, L2 ...}]

  Encadena dos o más listas (o sub-listas en una lista mayor) sin reordenar sus elementos, manteniendo todos aunque sean iguales.
  • Encadena [{1,2,3}, {4,1,2}] devuelve {1, 2, 3, 4, 1, 2}

Frecuencia [L]

Frecuencia [TF, L]

  Lista ordenada de las frecuencias (acumuladas si la condición TF es verdadera) de aparición de cada valor de la lista L (datos o textos).

 

Podemos usar el comando Unico[L] para realizar la correspondencia entre valores diferentes y frecuencias.

  • Si L = { "a", "a", "x", "x", "x", "b" } entonces
    Unico[L] devuelve {"a", "b", "x"} mientras que
    Frecuencia[L] devuelve {2, 1, 3} y
    Frecuencia[true, L] devuelve {2, 3, 6}

Frecuencia [L1, L2]

Frecuencia [TF, L1, L2]

  Lista ordenada de las frecuencias (acumuladas si la condición TF es verdadera) de aparición de cada valor de la lista L2 (datos o textos) en los intervalos de clase cuyos extremos constituyen la lista L1.

 

Todos los intervalos son semiabiertos [a, b), excepto el mayor que es cerrado [a, b]

  • Frecuencia[{1,2,3}, {1,1,2,3}] devuelve {2, 2}
Intercala [a, L, n]

Intercala [L1, L, n]

  Intercala el objeto a, o todos los elementos de la lista L1, en la lista L, en la posición indicada (si la posición es negativa, se cuenta desde el final).
  • Intercala [x², {1, 2, 3}, 3] devuelve {1, 2, x², 3}
  • Intercala [{11, 12}, {1, 2}, 3] devuelve {1, 2, 11, 12}
  • Intercala [(1,2), {1,2}, -1] devuelve {1, 2, (1, 2)}
  • Intercala [0, {1, 2, 3, 4}, -2] devuelve {1, 2, 3, 0, 4}
Intersección [L1, L2]   Lista con todos los elementos que pertenecen a ambas listas, descartando repeticiones.
ListaOrdinal [L]   Lista de posiciones, una vez ordenados de menor a mayor, de los elementos de la lista L.
  • ListaOrdinal[{3, 2, 2, 1}] devuelve {4, 2, 3, 1}
ListaPuntos [L] Lista de puntos correspondientes a las listas de pares de coordenadas que forman la lista L.
  • ListaPuntos[{{1, 2}, {3, 4}}] devuelve {(1, 2), (3, 4)}
ListaRaíces [L]   Lista de puntos del eje X con las abscisas de la lista L.
  • ListaRaíces[{1, 2}] devuelve {(1,0), (2,0)}
RangoAjustado [L]   Lista de posiciones, una vez ordenados de menor a mayor, de los elementos de la lista L. Si hay varios valores iguales, se promedian sus posiciones.
  • RangoAjustado[{3, 2, 2, 1}] devuelve {4, 2.5, 2.5, 1}
Unión [L1, L2]   Une las listas descartando repeticiones.
  • Unión[{1, 2, 3, 4}, {3, 2, 7}] devuelve {1, 2, 3, 4, 7}